Grüss Euch,
hier ist nun mein batch zum Aufnehmen mit DVBsVCR2.
Ich hab versucht möglichst schlüssig zu Beschreiben, wie man zu einem funktionierenden system kommt.
Es sind ja einige Hürden in Sachen "Programmnummern verteilen" zu nehmen.
Hier ist das batchfile, bitte als wdvb.cmd speichern.
(der Name taug mir nicht, hiess ursprünglich dvb.cmd, das ist mir aber wieder zu uneindeutig :)
=== speichern als wdvb.cmd ========================
Code: Alles auswählen
@echo off
setlocal
rem ========================================================================================
rem = Wrapper script for TV-Browser and DVBsVCR2 ===========================================
rem ========================================================================================
rem Function:
rem - creates a windows scheduler task to start a dvb recording program
rem - can delete scheduler tasks created by itself
rem - record/delete/error events are logged to a file
rem
rem Requirements:
rem - TV-Browser, from http://www.tvbrowser.org/
rem - Caprure Plugin, from http://www.vidrec.de.vu/
rem - DVBsVCR2, from http://dvbs.cyberhome.at/
rem - windows task scheduler "schtasks", Windows XP basic component
rem ========================================================================================
rem ========================================================================================
rem = Configuration ========================================================================
rem ========================================================================================
rem
rem - Set full path and file name to logfile
set log=c:\bat\dvb.log
rem - Set full path and file name to DVBsVCR2.exe
set recp=C:\Programme\DVBVCR\DVBsVCR2.exe
rem - Set full path to record folder
rem recordings are stored to this folder - i.e.: c:\my records
set recf=C:\rec ord
rem - Set channelname-folders option
rem recordings are stored to a channelname subfolder under the record folder - i.e.: c:\my records\ORF 1
rem set to "true" to enable, or any other value to disable.
set chaf=true
rem - Set language setting (needed for schtasks.exe)
rem possible values are "ger" or "us"
set rnls=ger
rem - Set user account for scheduler tasks
set runas_account=palnet\xandl
rem - Set password for user account
set runas_passwd=choose_your_own
rem - Now open TV-Browser to configure the capture plugin:
rem - open config dialog
rem - locate plugin section/Capture Plugin
rem - select wdvb.cmd in the "Pfad" dialog
rem - open "Zeit" page, enter values 2 and 10 for the delays
rem - open "Parameter" page, insert these values for record and delete:
rem record: record %CNU %SD %SMO %SY %SH %SMI %L %T2 %CNA
rem delete: delete %CNU %SD %SMO %SY %SH %SMI %L %T2 %CNA
rem - open "Sender" page, set each TV-Browser-channelname matching to DVBsVCR2-channelnumber
rem - If Channelnumbers are not yet configured in DVBsVCR2, do so now:
rem - open DVBsVCR2, click on menu File/Channel List
rem - click button "Channel & Number Editor", now scroll down to a prefered channel
rem - to enter a number matching your plugin settings, left click right beneth the
rem checkbox and move the pointer a bit (like renaming an icon with the mouse)
rem - relax :)
rem ========================================================================================
rem ========================================================================================
rem = Information ==========================================================================
rem ========================================================================================
rem
rem - DVBsVCR2 command line example:
rem C:\Programme\DVBVCR\DVBsVCR2.exe record "RTL Austria" c:\record /t 15:00
rem
rem - Capture plugin parameter, passed to wdvb.cmd
rem record %CNU %SD %SMO %SY %SH %SMI %L %T2 %CNA
rem
rem - Parameters from capture plugin are read and stored to environment in this order:
rem
rem parameter contents environment setting
rem ----------------------------------------------------
rem %1 mode MOD
rem %2 channel number CNU
rem %3 start day SD
rem %4 start month SMO
rem %5 start year SY
rem %6 start hour SH
rem %7 start minute SMI
rem %8 length in mins L
rem %9 title T2
rem %9 channel name CNA
rem
rem
rem - Taskname format for windows scheduler: TV-record_CNU_SD-SMO-SY_SH-SMI-00_L
rem
rem ========================================================================================
rem ========================================================================================
@echo off
echo.
echo -----------------------------------------------------------------------
echo Wrapper script for TV-Browser and DVBsVCR2
echo -----------------------------------------------------------------------
if not exist "%recp%" goto error_recp
if %rnls%\==ger\ set rmo=EINMAL
if %rnls%\==us\ set rmo=ONCE
set MOD=%1
set CNU=%2
set SD=%3
set SMO=%4
set SY=%5
set SH=%6
set SMI=%7
set L=%8
set T2=%9
shift
if not %9\==\ set CNA=%9
shift
if not %9\==\ set CNA=%CNA% %9
shift
if not %9\==\ set CNA=%CNA% %9
if %MOD%\==\ goto exit
if %T2%\==\ goto error_env
if %MOD%==record goto record
if %MOD%==delete goto delete
goto exit
:error_env
echo %DATE% - %TIME% - ERROR: failed to set environment, exit >> "%log%"
echo ERROR: failed to set environment, exit
echo.
goto end
:error_recp
echo %DATE% - %TIME% - ERROR: failed to locate DVBsVCR2 executable at %recp%, exit >> "%log%"
echo ERROR: failed to locate DVBsVCR2 executable at %recp%, exit
echo.
goto end
:record
if %chaf%\==true\ if not "%CNA%"=="" set recf=%recf%\%CNA%
if not exist "%recf%" mkdir "%recf%"
echo Creating recording task "TV-record_%CNU%_%SD%-%SMO%-%SY%_%SH%-%SMI%-00_%L%"
echo Channel: %CNA%
echo Start Date: %SD%.%SMO%.%SY%
echo Start Time: %SH%:%SMI%:00
echo Length: %L% minutes
echo Film Title: %T2%
echo.
%systemroot%\system32\schtasks.exe /create /SC %rmo% /TN TV-record_%CNU%_%SD%-%SMO%-%SY%_%SH%-%SMI%-00_%L% /TR "\"%recp%\" record %CNU% \"%recf%\" /t %L%:00" /ST %SH%:%SMI%:00 /SD %SD%/%SMO%/%SY% /RU %runas_account% /RP %runas_passwd%
echo %DATE% - %TIME% - %systemroot%\system32\schtasks.exe /create /SC %rmo% /TN TV-record_%CNU%_%SD%-%SMO%-%SY%_%SH%-%SMI%-00_%L% /TR "\"%recp%\" record %CNU% \"%recf%\" /t %L%:00" /ST %SH%:%SMI%:00 /SD %SD%/%SMO%/%SY% /RU %runas_account% /RP runas_passwd >> "%log%"
goto end
:delete
echo Deleting task "TV-record_%CNU%_%SD%-%SMO%-%SY%_%SH%-%SMI%-00_%L%"
echo Channel: %CNA%
echo Film Title: %T2%
echo.
%systemroot%\system32\schtasks.exe /delete /TN TV-record_%CNU%_%SD%-%SMO%-%SY%_%SH%-%SMI%-00_%L% /F
echo %DATE% - %TIME% - %systemroot%\system32\schtasks.exe /delete /TN TV-record_%CNU%_%SD%-%SMO%-%SY%_%SH%-%SMI%-00_%L% /F >> "%log%"
goto end
:end
echo.
echo.
echo ------------------------------------------------------------------------------------------------------------------------------------------- >> "%log%"
rem ========================================================================================
:exit
endlocal
=== speichern als wdvb.cmd ========================
Zur Verwendung:
File abspeichern, aufmachen, lesen, konfigurieren.
Bitte um feedback falls etwas nicht eindeutig ist.
Zu TV-Browser:
Beim Erstellen des scripts ist mir folgendes aufgefallen:
wenn ein recording via Kontextmenu gelöscht wird, muss ich trotzdem auf "Sendung aufnehmen" klicken ... das ist verwirrend. Irgendwie müssten da also ein Status geführt werden. Ich erwarte natürlich auf "[] löschen" zu drücken.
Bemerkung:
Ich möchte noch darauf hinweisen, dass bei mir die erstelleten tasks noch nicht automatisch starten. Manuell gestartet funktionierts wie erwartet. Die Verwendung von schtasks scheint eindeutig, ich denk ich hab da ein "Spezialproblem" mit den geplanten tasks. Der Funktion des batches dürft das aber nicht schaden, bitte auch hier um feedback.
baba
Xandl
.
